Домашнее задание для учащихся, успешно программирующих на языке программирования Turbo Pascal
program Vodoley_Problem; {задача о Водолее }
uses Crt;
const A_max = 7; { емкости сосудов }
       B_max = 5;
       Result = 1; { требуется получить }
function Vodoley (A_max, B_max : Word; MessageOn : Boolean) : Word;
{параметры функции - вместимость сосудов и флаг отключения сообщений; функция расчитывает число переливаний}
var A,B,Num: Word;{текущее содержимое сосудов и количество переливаний }
function Max (X, Y:Integer):Integer;{находит максимум двух чисел внутренняя для Vodoley}
Begin
	if X>Y then Max:=X else Max:= Y;
End; {Max}
function NOD (A, B : Integer):Integer; { находит НОД; внутренняя для Vodoley}
Begin
	while (A<>0) and (B<>0) do
		if A>B then A:=A mod B else B:=B mod A;
	NOD:= A+B;
End; {NOD}
procedure Message (S:String);{ печать сообщения; внутренняя для Vodoley}
Begin
	if MessageOn then Writeln (S,A:3,B:3);
	Inc (Num);
End; {Message}
procedure Do_kraev_A; {набираем полный A с помощью B; внутренняя для Vodoley}
Begin
while (A<A_max) and (A<>Result) do
begin
      if (B=0) then
		begin
		      B:= B_max;
		      Message ('Налить B ');
		end;
      A:= A+B;
      if (A>=A_max) then
			begin
			      B:= A-A_max;
			      A:= A_max;
			end	
		    else B:= 0;
      Message ('Перелить из B в A ');
end;
End; {Do_kraev_A}

Begin {Vodoley}
	A:= 0; B:= 0; Num:= 0;
        if (Result>A_max) and (Result>B_max) or (Result mod NOD(A_max, B_max)<>0)
		then
			begin
			      Message ('Невозможно ');
			      Vodoley:=0;
			      Exit;
			end
		else if Result=B_max
			then
				begin
				      B:= B_max; Message ('Налить В ');
				end
			else begin
				      Do_kraev_A;
				      while (A<>Result) and (B<>Result) do 
				      begin
					      A:= 0;
  					      Message ('Вылить из A ');
   					      if A_max>B_max 
						then begin
						       A:= B; B:= 0;
						       Message ('Перелить из B в A ');
						      end;
					      Do_kraev_A;
				      end;
			     end;
       Vodoley:= Num;
End; { Vodoley }
BEGIN
ClrScr;
if Vodoley(A_max, B_max, False)<Vodoley(B_max, A_max, False)
       then Writeln (Vodoley(A_max, B_max, True))
       else Writeln (Vodoley(B_max, A_max, True));
END.
        В этой программе функция Vodoley, вопреки сложившейся традиции, не только подсчитывает число переливаний, но и выдает сообщения об этих манипуляциях. Для отключения этих сообщений задействован булевский параметр MessageOn. В основной программе при отключенных сообщениях сравниваются результаты "прямого" и "обратного" переливаний, а затем в режиме включенных сообщений распечатывается наименьший результат.
         Иногда условие задачи о Водолее видоизменяют. Требуют получить заданное количество воды не в одном из сосудов, а в большой бочке, которая в самом начале пуста. Ясно, что такое изменение задачи позволяет отвлечься от переливаний из сосуда в сосуд и сосредоточиться только на представлении результата в виде суммы чисел, кратных данным.
         В основе работы алгоритма для двух сосудов лежит известный инвариант алгоритма Евклида: НОД двух чисел не изменится, если большее из них заменить их неотрицательной разностью. Числа представляются в виде  и , причем вначале p=s=1, q=r=0. Кроме того в алгоритме учтен тот факт, что Res?НОД(A,B)=НОД(Res?A, Res?B).

const
       A = 14; {сосуды}
       B = 4;
       Res = 6; {требуется получить; должно быть кратно НОД(A,B) }
Var m,n,p,q,r,s : Integer;
BEGIN
       m:= A;n:= B; p:= 1; q:= 0; r:= 0; s:= 1;
       {инвариант: НОД (A,B) = НОД (m,n); m,n >= 0 m = p*A + q*B; n = r*A + s*B }
       while (m<>0) and (n<>0) do
       begin
      	 if (m >= n) 
		then begin m:= m-n; p:= p-r; q:= q-s;end
     		else begin n:= n-m; r:= r-p; s:= s-q; end;
       end;
       if (m=0) 
		then Writeln (Res div n*r:3, Res div n*s:3)
		else Writeln (Res div m*p:3, Res div m*q:3);
END.
         Эта же идея "работает" и в случае, когда сосудов не два, а больше. Например, ключ к получению в бочке 1 литра с помощью сосудов емкостями по 17, 32 и 45 литров лежит в представлении 1=17?(-44)+32?22+45. Множитель, стоящий при каждом числе соответствует количеству переливов данным сосудом (положительное значение – в бочку, отрицательное – из бочки).